Pittsburgh Supercomputing Center

Advancing the state-of-the-art in high-performance computing,
communications and data analytics.

ANSYS input data

```/verify,bm-8
/verify,off    ! /verify is used by compare to determine the jobname
/title, bm-8, SMP ANSYS Benchmark Test - PCG Structural - Wing Model
/COM    ANALYSIS TYPE: STATIC, STRUCTURAL
/COM    SOLVER CHOICE: PCG
/debug,stat
/nopr
dofs   = 5
eltype = 45
np     = 1
! define parameters
aspect=1.0
level=1
dof_nd=3
ndofs=dofs*1000000
*if,ndofs,lt,50001,then
a_size=.1
*elseif,ndofs,lt,100001,then
a_size=.075
*elseif,ndofs,lt,350001,then
a_size=.050
*elseif,ndofs,lt,2000001,then
a_size=.030
*elseif,ndofs,lt,7500001,then
a_size=.015
*else
a_size=.010
*endif
/PREP7
shpp,off
ET,1,PLANE42               ! Define PLANE42 as element type 1
ET,2,eltype                ! Define SOLID95 as element type 2
*if,eltype,eq,95,then
KEYOPT,2,11,1
*endif
MP,EX,1,38000
MP,DENS,1,1.033E-3
MP,NUXY,1,.3
K,1                        ! Define keypoint 1 at 0,0,0
K,2,2                      ! Define keypoint 2 at 2,0,0
K,3,2.3,.2                 ! Define keypoint 3 at 2.3,.2,0
K,4,1.9,.45                ! Define keypoint 4 at 1.9,.45,0
K,5,1,.25                  ! Define keypoint 5 at 1,.25,0
LSTR,1,2                   ! Create a straight line between keypoints 1 and 2
LSTR,5,1                   ! Create a straight line between keypoints 5 and 1
BSPLIN,2,3,4,5,,,-1,,,-1,-.25   ! Create a B-spline
AL,1,3,2
ESIZE,a_size
AMESH,1
*get,a_nodes,node,,count
*if,eltype,eq,95,then
zdiv=ndofs/(11*a_nodes) - 1
*else
zdiv=ndofs/(3*a_nodes) - 1
*endif
zlth=a_size*zdiv*aspect
zdiv=nint(zdiv)
esiz,,zdiv
*if,zlth,le,0,then
zlth=1
*endif
TYPE,2
VEXT,ALL,,,,,zlth
modmsh,detach
allsel,all
FINI
/SOLU
ESEL,U,TYPE,,1        ! Unselect element type 1
NSEL,S,LOC,Z,0        ! apply zero B.C.s to one end of wing
D,ALL,ALL
NSEL,ALL
ANTYPE,STATIC
NSEL,S,LOC,Z,zlth        ! apply a small displacement to opposite end of wing
d,all,uy,-0.1
NSEL,ALL
eqsl,pcg
pcgopt,1
outres,all,none
outres,nsol,last
outres,rsol,last
solve,,,,,nocheck
fini
*list,,PCS
/exit,nosave
```