* create MMFF molecule and solvate, followed
* by creation of images and energy minimization
*

bomlev 5

! read CHARMM rtf with MMFF atom types after masses
read rtf  card unit  5
* TIP3P RTF
*
   20    1                   ! Version number
MASS    31 HOH    1.00794 H  ! HYDROGEN IN H2O
MASS    70 OH2   15.9994  O  ! OXYGEN ON WATER

AUTOGENERATE ANGLES
DEFA FIRS NONE LAST NONE

RESI OH2    .000   ! MMFF WATER MODEL
GROUP
ATOM OH2  OH2    -0.86
ATOM H1   HOH     0.43
ATOM H2   HOH     0.43
BOND OH2 H1  OH2 H2   !    H1   H2  ! THE LAST BOND IS NEEDED FOR SHAKE

END

!stream MMFF parameters and activate MMFF
stream mmff_setup.str
 
!read solute molecule and generate
read merck name am07a.mrk
generate
update inbfrq 1 ihbfrq 0 CUTNB 9. CTOFNB 8. CTONNB 3. cdie e14fac 0.75
energy

!generate solvent and append coordinates
read sequence OH2 125

generate SOLV   !use mmff atom types

open unit 20 read form name wat125.crd
read coor card unit 20 append

! delete waters overlaying the solute
dele atom sele ( .byres. ( segi SOLV .and. type oh2 .and. -
     ( ( .not. segi SOLV .and. .not. hydrogen ) .around. 2.8 ) ) ) end

energy

set 6 15.517182
set 7 15.517182
set 8 15.517182

!faster on <- this is default
faster off

! Read in image transformation files and set-up image centering
crystal define cubic @6 @7 @8 90. 90. 90.
crystal build cutoff 9. noperations 0

!apply image centering to maintain box integrity
image byresidue xcen 0.0 ycen 0.0 zcen 0.0 sele segid SOLV end

!
energy inbfrq -1 imgfrq -1 cdie e14fac 0.75 switch vswitch -
       CUTIM 9. CUTNB 9. CTOFNB 8. CTONNB 7.

shake bonh tol 1.0e-8 param

mini abnr nstep 10 tolg 0.01

stop

open unit 20 write unform name @9mmff.dcd 

! Run dynamics in periodic box
dynamics verlet strt timestep 0.001 nstep 100 nprint 10  iprfrq 10 -
     firstt 298.0 finalt 298.0 twindl -5.0 twindh 5.0 -
     ichecw 1 teminc 0 ihtfrq 0 ieqfrq 20 -
     iasors 0 iasvel 1 iscvel 0 -
     iunwri -1 nsavc 10 nsavv 0 iunvel 0 -
     iunread 0 iuncrd 20                 - !{* Nonbond options *}

mini abnr nstep 10 tolg 0.01

stop