* Read MOL2 database into MMFF and perform 
* minimization and vibrational analysis
*

stream mmff_setup.str

!open output datafile
open unit 50 write form name test_db.dat

!open mol2 database; this is similar to the
!output from DOCK 
!http://www.cmpharm.ucsf.edu/kuntz/dock.html
!
open unit 60 read  form name mmff_db.mol2

!mmff_db.mol2 contains all compounds in the mmff_mol2.inp
!AM07A
!AR07A
!CA07A
!CE07A
!CJ07A
!HL07A
!IM07A
!NC07A
!NH07A
!OH07A
!OR07A
!RA07A
!RE07A
!SR07A
!BIPHENYL

!read individual structures, generate, write MERCK .mrk file,
!perform minization and write energy to data file

set 1 ce07a
read db ce07a unit 60
goto mmfftst
label ce07a

set 1 NH07A
read db NH07A unit 60
goto mmfftst
label NH07A

set 1 BIPHENYL
read db BIPHENYL unit 60
goto mmfftst
label BIPHENYL

stop

label mmfftst

!generate structure
generate

!write MERCK format file
open unit 20 write form name test_@1.mrk
write merck unit 20
* test 
*

!create nobond list and calculate energy; note special terms required by MMFF
!
update inbfrq -1 ihbfrq 0 CUTNB 999. CTOFNB 888. cdie e14fac 0.75
energy

!energy minimization
mini nrap nstep 20 nprint 2

!write final energy to database
write title unit 50
* @1  ?ener
*

!perform vibrational analysis
vibran
diag
end

goto @1